buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.4'
        classpath files('gradle/witness/gradle-witness.jar')
    }
}

apply plugin: 'java'
apply plugin: 'application'
apply plugin: 'maven'
apply plugin: 'witness'
apply plugin: 'com.github.johnrengelman.shadow'

group = 'network.bisq'
version = '0.7.1-SNAPSHOT'

sourceCompatibility = 1.8

mainClassName = 'bisq.desktop.app.BisqAppMain'

tasks.withType(AbstractArchiveTask) {
    preserveFileTimestamps = false
    reproducibleFileOrder = true
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

sourceSets.main.resources.srcDirs += ['src/main/java'] // to copy fxml and css files

repositories {
    jcenter()
    maven { url 'https://jitpack.io' }
    maven { url 'https://raw.githubusercontent.com/JesusMcCloud/tor-binary/master/release/' }
    maven { url 'https://dl.bintray.com/jerady/maven' }
}

dependencies {
    compile 'network.bisq:bisq-p2p:-SNAPSHOT'
    compile 'network.bisq:bisq-core:-SNAPSHOT'
    compile 'network.bisq:bisq-common:-SNAPSHOT'
    compile 'org.controlsfx:controlsfx:8.0.6_20'
    compile 'org.reactfx:reactfx:2.0-M3'
    compile 'net.glxn:qrgen:1.3'
    compile 'de.jensd:fontawesomefx:8.0.0'
    compile 'de.jensd:fontawesomefx-commons:8.15'
    compile 'de.jensd:fontawesomefx-materialdesignfont:1.7.22-4'
    compile 'com.googlecode.jcsv:jcsv:1.4.0'
    compile 'com.github.sarxos:webcam-capture:0.3.12'


    compileOnly 'org.projectlombok:lombok:1.16.16'
    annotationProcessor 'org.projectlombok:lombok:1.16.16'
    testCompile('org.mockito:mockito-core:2.8.9') {
        exclude(module: 'objenesis')
    }
    testCompile 'org.jmockit:jmockit:1.30'
    testCompile 'org.powermock:powermock-module-junit4:1.7.1'
    testCompile 'org.powermock:powermock-api-mockito2:1.7.1'
    testCompile 'org.springframework:spring-test:4.3.6.RELEASE'
    testCompile 'com.natpryce:make-it-easy:4.0.1'
    testCompileOnly 'org.projectlombok:lombok:1.16.16'
    testAnnotationProcessor 'org.projectlombok:lombok:1.16.16'
}

build.dependsOn installDist
installDist.destinationDir = file('build/app')

// To update the `dependencyVerification` block below:
//
// 1. Remove the block entirely
// 2. Replace the block with the following command:
//
//    ./gradlew -q calculateChecksums | grep -v network.bisq:bisq- >> build.gradle
//
// 3. Run `git diff` to verify that expected hashes have changed
// 4. Commit the changes

dependencyVerification {
    verify = [
    ]
}